Any multi-channel audio tips?

[hatchfactory]

I'm trying to take the leap from hobbyist to commercial developer and I'm nearing completion of code for a set of children's interactive e-book apps. I'm to the point of heavy stress testing on multiple devices. Where my app seems fairly stable (but not perfect when pushed) on a Nexus 7, Kindle Fire HD, HTC G2, Viewsonic Gtablet and a Huawei Fusion. Testing on a Samsung Galaxy SII however playing audio on a particular channel repeatedly consistently causes the app to lock up and crash, and on a Samsung Infuse app goes black and fails to launch.

The apps weak spots on all devices seem to be when 2 sounds seem to play on top of each other on the same track. For the last 16 hours I've been trying to find ways to make my audio code a little more android friendly, so I post here hoping that some of you more experienced livecoders could nudge me in the right direction.

The first app uses some 120 .mp3 sounds throughout, so I made a function for simplicitys sake. Sometimes sounds are played mid- animation loops etc. but nothing seems intensive or too tight for messages. Is a function the best way to accomplish this? My other thought after reading various threads was to add a little breathing room between sounds played for os/livecode communication hence the "wait for 0 millisecs with messages". Any thoughts for increased stability?

In a button:

Code: Select all

 do playSound(dolphin)

 do playSound(ocean, channel3, looping)

--> ? or should it be ?

return playSound(ocean, channel3, looping)

In the stack script:

Code: Select all

function playSound whatSound, whatChannel, whatType
   if whatChannel is empty then
      put "channel1" into whatChannel
   end if
   if whatType is empty then
      if mobileSoundChannelStatus(whatChannel) is "playing" then
         mobileStopPlayingOnChannel whatChannel
         wait 0 millisecs with messages
      end if
          put "now" into whatType
   end if
    if the environment is not "mobile" then
      put  "audio/"&whatsound&".wav" into tSndpath
      if whattype is "looping" then
         play tSndPath looping
      else
         play tSndPath
      end if
   else
      put specialFolderPath("engine")&"/maudio/"&whatsound&".mp3" into tSndpath
      mobilePlaySoundOnChannel tSndpath, whatChannel, whatType
   end if
   return empty
end playsound

[Klaus]

Hi hatchfactory,

1. welcome to the forum!

2. You created a function, so you need to write:
...
put playSound("ocean", "channel3", "looping") into tValueReturnedFromTheFunction
## "ocean", "channel3" and "looping" are in fact and need to be treated as STRINGS, so we need to QUOTE them.
...

But you better use a command here like this and a WAIT should not be neccessary:
Try this:

Code: Select all

command playSound whatSound, whatChannel, whatType
  
  ##!!!
  if the environment is not "mobile" then
    put  "audio/"& whatsound &".wav" into tSndpath
    if whattype is "looping" then
      play tSndPath looping
    else
      play tSndPath
    end if
    
    ## Everything else only works on MOBILE, so we simply get out of here NOW!
    ## This avoids unneccesary long an nested IF... TEHN... clauses and makes 
    ## the code better readable!
    exit playSound
  end if
  
  if whatChannel = empty then
    put "channel1" into whatChannel
  end if
  if whatType = empty then
    if mobileSoundChannelStatus(whatChannel) is "playing" then
      mobileStopPlayingOnChannel whatChannel
    end if
    put "now" into whatType
  end if
   
  put specialFolderPath("engine")&"/maudio/"&whatsound&".mp3" into tSndpath
  mobilePlaySoundOnChannel tSndpath, whatChannel, whatType
end playsound

You should check and work through these stack to get the basics of Livecode (very important!):
http://www.runrev.com/developers/lesson ... nferences/

Hint:
The only documantation for the mobile platform are the "Android/iOS Release Note"
This is a PDF that you can access in Livecode: Menu: Help!


Best

Klaus

[hatchfactory]

Thanks for the welcome and help Klaus , good points you bring up. I will change things and report. I will study the scripting conference links, the release notes, to me, are already an invaluable resource.

[Klaus]

Okie Dokie

[hatchfactory]

in changing

Code: Select all

function playSound whatSound, whatChannel, whatType 

to

Code: Select all

command playSound whatSound, whatChannel, whatType 

it seems whatChannel and whatType are ignored, sounds with "looping" no longer play

inserting for diagnotics :

Code: Select all

put whatChannel&&whatType into msg box 

currently yields nothing

should I be making whatChannel and whatType global variables?

I guess I need to read more on the difference between functions and commands...

edit: got it working after reading up some of those scripting conference docs.

I changed the calls from:

Code: Select all

playsound (Gullscry, channel2, now)

to:

Code: Select all

playsound "Gullscry", "channel2", "now"

now with quotes instead of parenthesis for commands.

now on to mobile testing...

[Klaus]

Hi hatchfactory,

...
should I be making whatChannel and whatType global variables?

No, these are just "parameters" so not neccessary!

I changed the calls from:

Code: Select all

playsound (Gullscry, channel2, now)

Yep, that's FUNCTION syntax!

Code: Select all

playsound "Gullscry", "channel2", "now"

Correct!

Code: Select all

playsound "Gullscry", "channel2", "now"

now with quotes instead of parenthesis for commands

Not that I mentioned this in my first answer...

Hint: QUOTES are not a replacement for PARENS here!
You are passing STRINGS, so QUOTES are a MUST!


Best

Klaus

[hatchfactory]

Not that I mentioned this in my first answer...

Hint: QUOTES are not a replacement for PARENS here!
You are passing STRINGS, so QUOTES are a MUST!

Yes, you did, and that was the hint I needed to get it fixed

End results:
Klaus, I made all the changes you suggested and fixed some 120 calls. which has greatly increased the stability of the app on almost all of the devices. No crashes except the Samsung SII, on which the app was highly unstable, will still crash the app but only %10 as much as it used to on stress testing.
All in all I am very happy with the results, Thank you for your much needed Help. I would offer to bake you some cookies. The app seems now publish-able.

[Klaus]

My pleasure!
Good luck with your app!